Skyrim Console Remove Spell

Posted on 17.08.2019by admin

The UESPWiki – Your source for The Elder Scrolls since 1995

Skyrim Console Command Remove Spell Effect

Jump to: navigation, search

This page or section is incomplete. You can help by adding to it.
For more information, see the help files, the style guide, and this article's talk page.

The console is a powerful in-game tool only available to PC players. From the console it is possible, while playing the game, to enter commands that will alter most aspects of gameplay, and it is also possible to obtain detailed information about NPCs, creatures, and other items in the game.

3Commands
4Using Batch Files with the bat Command

General Information[edit]

The console can be accessed in-game by toggling the 'tilde key' (the actual key can be ~, º, ¬, ,^, , §, ², etc., depending on your keyboard layout), found near the 1 and Esc keys on most keyboards. The console prompt will appear in the lower left-hand corner of your screen. The console can also be used as a pause function during scenes or dialogue that cannot otherwise be paused. You can scroll the console output using the Page Up and Page Down keys. Console commands are not case-sensitive—entering any of tai or TAI or TaI will toggle AI. After you type a command, press the Enter key to activate it. You will see the command you just entered displayed above the input area.

Skyrim console commands perks Tm using tm command every menu item get disable from the console window. By using tm command you can, it makes easy to capture a screenshot of gameplay.

Many commands are targeted: this means that you may use player.command to affect the player character; for example, type player.setav carryweight 1000 will set the Player's Carry Weight at 1000. Or, you may want to target the NPC/actor, by first typing prid <RefID>, Enter. Then, type the command by itself, setav carryweight 1000, to affect the NPC, specified by <RefID> (Note: including the zeroes at the beginning of the RefID when targeting NPCs may produce a 'command not found' error. That can be evaded though by placing the RefID in quotes, e.g. '000A2C94'.setav carryweight 1000 will set Lydia's Carry Weight at 1000).

You may also target an NPC or object in the console by clicking on them, and then run command to affect the NPC or object. When an NPC or object is targeted in this way, their hex code (RefID) will be displayed at the top of the console. For example, to unlock a door, open the console, click on the door so it is the active object in the console (its RefID is shown at the top of the screen), then type unlock. When multiple objects overlap, use the mouse wheel to scroll through different RefIDs until the correct one is selected. When playing on multiple monitors, the cursor will display in the secondary monitor but clicking it will select the object in the same area of the primary monitor.

Commands which are abbreviated (for example: tai) can also be run by using their full name; thus, ToggleAI is synonymous with tai, and GetActorValue is synonymous with getav. In most cases, the long command is an obvious progression from the abbreviation. Also, most SetSomething commands have a counterpart GetSomething, even if the counterpart isn't shown here.

Some commands require a form ID. Most articles on objects provide the ID or IDs for those items. In addition, the Help command can be used to locate IDs. Help 'elven sword' 0 would provide a list of all game objects with elven sword in their names. This can be used for items, spells (Help firebolt 0), and perks (Help juggernaut 0).

If you don't know what you're doing, using console commands can cause your game to malfunction! Executing the wrong command can cause your game to stop working normally; furthermore, you may not become aware of such malfunctions right away, and you may not be able to trace their cause. They can cause problems like making quests impossible to complete, altering your game's display, all kinds of game behaviors, your ability to play your character, and your ability to play the game at all. Solutions are not always easy, and may involve losing saved games or reinstalling your game.

Create and archive a permanent saved game before using the console. (This mitigates only some kinds of risks.) If you need to use the console to fix a glitch, try to use the least-powerful command possible.

Your best bet for help if your game is crashing or not operating properly due to a console issue is on the producer's official forums. You may see if someone in this wiki's Discord server has a suggestion. You may not get any kind of answer right away, or a solution at all. You might also try asking a question on this article's talk page with the same idea: you may or may not receive a timely reply to your question or problem, and you may not receive a solution at all.

Accessing the Console with Non-English Keyboards[edit]

If you are using a non-US keyboard, the tilde (~) / grave accent (`) key might not work, or there may be no key with such markings. Often, the correct key to use is the key below Esc and above Tab (↹), where the tilde/grave key is on a US keyboard. See the following table for specifics:

Keyboard	Key	Notes
Arabic	`ذ`
Danish	`½`
French	`²`
Finnish Norwegian Swedish Swiss	`§`
German	`^`	The circumflex or 'hat' character is usually used together with a normal letter to create letters like `ê` or `ô`. To avoid problems, hit the space bar after opening the console, then delete the `^` that appears.
Hungarian	`0`	If you want the character `0` to appear in console input, you must press the one on your numeric keypad. Otherwise, the console will close.
Italian Portuguese (Portugal)
Portuguese (Brazil)	`'`
Spanish	`º`/`ª`
Turkish Q	`'`

The mouthpiece of the gaming generation, The Escapist aims to capture and celebrate the contemporary video gaming lifestyle and the diverse global video game culture by way of in-depth features.
Jun 3, 2019 - Skyrim Console Commands are an essential tool that players use to enter cheats. Game after using the command and disable autosaves in the main menu. An all item room is coc QASmoke. Psb - Give all spells to player.

Another possible solution is to install AutoHotKey and set up a shortcut to send the tilde key code the game is expecting. Add the following lines to your AutoHotKey script and it will map F12 to grave accent (`) and Shift+F12 to tilde (~). (The grave accent key is the same physical key as tilde on US English keyboards.)

On some systems you may need to use the less optimal mapping:

Commands[edit]

How to Read the Command Table

When a command requires arguments (e.g., additem <Item ID> <qty>), the brackets <> indicate that <ID> should be replaced with the appropriate ID, and <qty> with the appropriate quantity. The brackets are not part of the syntax. So additem <ID> <qty> becomes additem 0002299c 1.

Furthermore, all REFIDs, faction, weather etc can be entered without the leading zeros, eg: additem 2299c 1 has the same effect as above.

Command Effect Notes

Toggle Commands[edit]

These commands toggle settings on and off.

animcam Toggle animator camera Toggles a 3rd person camera mode that lets you rotate and zoom the camera around the player without changing the direction the player model is facing.

psb Player Spell Book Gives the character a complete spell book, including the shouts, and unlocks bestial abilities. Dragon souls are still required for shouts. This can crash Skyrim.

s1st Shows 1st person model in 3rd person This only works in 3rd person. It shows your 1st person arms behind your character in 3rd person. You control the 3rd person model, but the 1st person arms mimic your swings. It looks like you're controlling a character that's controlling another character.

sucsm <number> Changes the speed of the free-flying camera (UFO cam) Example: sucsm 50 after typing tfc will allow the camera to move about five times faster than its default speed. The full command name is 'SetUFOCamSpeedMult'.

tai Toggle AI Toggles AI (Artificial Intelligence) processing off or on. This command is targeted; if no actor is selected it will turn off/on AI processing globally.

tb Toggle Borders Toggles cell border visibility. Borders appear as a thin white line on the terrain.

tc Toggle controls driven If used when highlighting an NPC, will transfer control to said NPC, but any command input will be passed in addition to the player unless player.tc is used to remove control.

tcai Toggle Combat AI Toggles Combat AI processing off or on.

tcl Toggle collision (clipping, noclip) Essentially, you can fly. Point in a direction and move wherever you want. You can also move through buildings and even the landscape. This command is targeted; if no actor is selected it will turn off collision for the player while keeping other actors stuck in place. It is possible to deselect any target reference by double clicking the same object or area in the landscape, which will cause 'tcl' to default itself to target the player.

tdetect Toggle AI Detection Disables and enables AI detection, meaning if it is toggled off, NPCs won't be able to 'see' you, or anyone else, even if you're right in front of them or attacking them.

teofis Toggle End-Of-Frame ImageSpace Disables blur, contrast adjustment, fades back in from a black screen, and a few other things. Will give a huge framerate boost on 'weak' video cards, at the expense of some prettiness.

tfc <1> Freeflying camera Sets your controls to move the camera around, instead of the player. Use with 3rd person view to get a good look at your character. Adding the '1' tag at the end freezes all the environment, but still allows you to move around with the camera.

tfow

Toggle Fog of War

Despite the name, this simply disables the local map, leaving the player and door markers on a black void. Has no effect on the world map.

Note: There seems to be a bug when activating this when mining or woodcutting that causes your character to disappear and not be able to attack or go in to third person. Loading a previous save before this happened seems to fix this.

tg Toggle grass Toggles display of grass.

tgm

Toggle god mode

No damage taken, no magicka consumed, no stamina used, no encumbrance, unlimited arrows, no shout cooldown. You can only use this on yourself.

Note: God mode will not protect you from scripted damage, such as that from lightning in the Soul Cairn, or damaging light or darkness in Twilight Sepulcher and Apocrypha, respectively. It also will not prevent you from contracting a disease.

tim Toggle immortal mode Everything behaves as normal except you cannot die as a result of being reduced to 0 health. You can only use this on yourself. If you are decapitated or bitten and thrown by a dragon while using this, it can have some quite frustrating results (e.g. you will walk around with your head cut off).^{[verification needed — see talk page]} These effects can be avoided by setting the character as essential.

tll Toggle LOD Dramatically reduces draw distance for a performance gain and might solve glitches related to LOD.

Toggle menus (HUD)

'Menus' refers to the Heads-Up Display (HUD) on the screen: the health/magicka/fatigue meters, your current weapon and spell, the compass, etc. This also removes the cross-hair if it's present. This command is useful for taking screenshots without all the clutter.

Note: the tm command will toggle off ALL menus, including the console menu itself! To avoid confusion:

Press ~.
Type 'tm' and press ENTER.
At this point, your console is still open but you cannot see it! Press ~ again to close it.
When you wish to toggle menus on again, press ~ to open the console (you will not see anything, but the game action will pause).
Type 'tm' and press ENTER.

Also see csb.

tmm <show?>(,<discovered?>,<includehidden?>) Show/hide all map markers <show?> should be 1 to show all markers, or 0 to hide all markers. Hiding markers hides all markers - including the city markers that are automatically visible at the beginning of the game. When adding markers, the 2nd parameter <discovered?> determines if the ones you add are set as discovered (1, default) or not (0), and the 3rd parameter <includehidden?> is all (1) or all but hidden (0,default) (e.g., to add all undiscovered markers without fast travel, enter tmm 1,0,0).

ts Toggle sky Toggles display of the sky.

tscr Toggle script processing. Toggles script processing off or on globally.

tt Toggle trees Toggles display of trees.

twf Toggle wireframe Shows wireframe in red or opaque.

tws Toggle water system Toggles display of water (display underwater remains unchanged).

Targeted Commands[edit]

These commands require a target reference. Select one with the mouse in the console, use the prid command, prefix the command with player to target the player character or prefix the command with a RefID to target something else.

additem <item ID> <count> <flag (optional)> Give a character the specified amount of an item E.g., player.additem 000669A5 5 will add five leeks to your player's inventory. The effects of <flag> are unknown, but it probably refers to ownership and stolen status. Changes to an NPC's inventory will usually appear immediately if you're pickpocketing them when you open the console. It is possible to remove items with this command by using negative numbers.(Item ids: Skyrim:Items)

addperk <perk ID>

Give a character the selected perk

For perk ID codes, see the page for the perk's corresponding skill, indexed at Skills. To find the perk ID code in-game, try help <perkname> 0.

E.g., player.addperk 000c44c0 would give your player the perk 'Adept Destruction'.

addspell <spell ID>

Add a specific spell to a character's available arsenal.

Works with powers, abilities, blessings, and diseases, but not shouts. For a spell's ID code, see the page for its corresponding magic school, indexed at Spells. For other applicable IDs, see: Powers and Abilities, Blessings, or Diseases. This command does not work with dragon shouts; to add those, see the teachword command.

Here are some examples (note how adding certain magic effects can have unanticipated consequences):

player.addspell 00092c48 will add the 'Beast Form' power to the player's spell book, essentially turning you into a werewolf.
player.addspell 000b8780 will add the 'Sanguinare Vampiris' disease, turning your character into a vampire over the course of 3 ingame days. (Diseases will only be added after a random number is checked. The chance to contract 'Sanguinare Vampiris' is 10%.)
player.addspell 000d2056 will add the 'Ghost Ability' effect, essentially turning your character into a ghost. (If you remove this spell again, you will need to reset the actor's opacity with setactoralpha command.)

Adding certain permanent abilities this way (e.g., Ancient Knowledge) will merely add their name to the list of active effects, but will not actually give the expected benefits. That requires changing the appropriate Actor Value Indices separately.

addfac/addtofaction <faction ID> <faction rank>

Add a character to a faction.

Valid numbers for the faction rank vary, but 0 will always add the actor with the lowest possible faction rank and -1 will remove the actor from the faction.

Examples for some factions that can't usually be joined in the game, are given below:

factionid	faction	notes
0005C84D	PotentialFollowerFaction	Gives the NPC all necessary dialogue to be selected as a new follower.
00019809	PotentialMarriageFaction	Gives the NPC all necessary dialogue to be available as a spouse. (Will not work with all races or NPCs with unique voices.)
xx004290	PotentialChildrenFaction	Gives the NPC child necessary dialogue to be adopted. (May not always work, some children will disappear all day and just sleep at your home.) xx = Hearthfire loading order number
0005A1A4	Player Ally Faction	Will turn the selected NPC into a friendly character.
000E0CD9	Bandit Ally Faction	If used on the player, most bandits will no longer attack.
000E0CDA	Warlock Ally Faction	If used on the player, most warlocks and necromancers will no longer attack.
000E0CDB	Draugr Ally Faction	If used on the player, most draugr will no longer attack.

advlevel Advance a character's level by one. advlevel Adds one level to your character's current level. You are not given the option to increase an attribute, are not awarded any perk points, nor, obviously, will any of your skills improve. This command may therefore seem of limited value; however, remember that enemies get tougher as your level increases - so if you're a Tamriel veteran and have already cranked the difficulty to 'Legendary' but still crave more of a challenge, using advlevel to add ~10 levels to your character (that's ten levels without skill increases, attribute gains, or new perks!) should certainly make the enemies more difficult.(though remember that the loot will also be leveled)

AdvSkill <skill> <nn> Advance the specified skill. AdvSkill registers the increase and will count towards your next levelup.
The full list of values recognized by AdvSkill is provided at Actor Value Indices. The number represents the experience level to add to the skill (e.g., player.advskill destruction 1 will only add 1 experience towards the next skill increase, it will not advance Destruction 1 skill level). Some skills require far more experience points than other skills, crafting skills level quickly with few points, but armor skills require much higher numbers.
See the incPCS command for an alternative means of leveling skills, which in comparison does not use the relative-value experience points; however, incPCS can only increase a skill by one level per use.

cast <spell ID> <target ref ID> <source>

Casting the specified spell at the target.

If no target, set <target ref ID> to player.

<source> could be:

left - left hand
right - right hand
voice - voice/power

Note: casting an unequipped spell is allowed, the spell will be automatically equipped. But it will cause SkyrimVR not to display the hand's spell effect when you stop casting.

Example:

First player.equipspell 12fcc right, then player.cast 12fcc player right will cast Healing to player self.
First player.equipspell 12fcd right, then player.cast 12fcd player right will cast Flames to player pointing.
First player.equipspell 12fd2 left, then player.cast 12fd2 1aa65 left will cast Heal Other to your follower Benor.

Casting shout with this command is also works:

player.cast 13f3a player voice: Unrelenting Force - Fus Ro Dah
player.cast 13f39 player voice: Unrelenting Force - Fus Ro
player.cast 13e09 player voice: Unrelenting Force - Fus

The spell IDs of a shout are completely different from the shout's ID and are considered as three different spells. You can find these IDs from CreationKit of Skyrim > Magic > Spell > Voice Power.

Note: The player's voice will not be played when casting shout from console.

For more information, see [Cast - Creation Kit].

completequest <quest ID> Complete the quest instantly. Be careful when using this command. Often, it merely makes the quest in the Journal become a completed quest. However, the related actors or NPCs to the quest may not recognize that you have completed a quest/task in order to give you a following quest/task. Quest IDs can be found in Quests.

DamageActorValue <attribute> <nn>

Damage value of attribute by <nn> amount

Example: player.damageactorvalue health 50 causes you to lose 50 health as if you just took damage. It will still recover the same way it normally does. Attributes can become negative. Can be restored with restoreactorvalue. This is a better option than modAV for temporary debuffing, since it can be restored to its original value easier. Stacks with 'modAV' effects. Skills/attributes damaged with damageactorvalue will still appear white, but will correctly restore to what they really are. Can be used to kill NPCs.
Also see RestoreActorValue

The full list of attributes is provided at Actor Value Indices

disable Don't render the selected object (includes actors.) The object will be made invisible, collision will also be turned off and AI won't process on the object, but scripting on the object will run (unlike Oblivion, where it would instantly crash to desktop, the player can't be disabled).
Also see enable

dispelallspells Dispel all temporary spell effects on target Example: player.dispelallspells dispels any magic effect on the player including buffs/debuffs (not attributes/skills changed with the console), potions/poisons, DoT effects, and activated powers (except beast form and other morphs).

drop Force drop items from a character's inventory You may select a character and use the command Drop <base ID> <amount> to drop any items in their inventory by force, including normally undroppable quest items. You may need to use Showinventory to get a detailed list of items and get the correct IDs you need.

duplicateallitems <container/NPC refID> Duplicate all items in the targeted container and places them in the given container. Example: Selecting an NPC with the mouse then entering duplicateallitems 89c79 will copy all items in the NPC's inventory and place the duplicates into the container with refID 89c79. You can get the container/NPC's refID by clicking on them and committing the ID to memory before selecting the container/NPC which has the items you want to copy. You can also type in the refID of the container/NPC with the items to be copied before the command with a period in between instead of selecting anything with the mouse. For example, entering a2c94.duplicateallitems 89c79 will copy all items from Lydia's inventory (whose refID is a2c94) and place the duplicates into the container with the refID 89c79.
Also see removeallitems

enable Render the selected object (includes actors.) Undoes disable, making the object and its collision and AI appear in the world again.
Also see disable

equipitem <Item baseID> <0/1> <left/right>

Equip selected NPC with Item

With a selected NPC, you can typically use equipitem <Item ID> for use (if one is not already in their inventory, it will be added); the player-character equivalent is player.equipitem.

An optional extra parameter is 0 or 1: the latter seems to make the item not be unequippable (sometimes – the results are not entirely consistent), e.g. to keep a weapon drawn at all times; the default is 0, and leaves the item contextually unequippable (or resets it to be so, if 1 was used earlier).
A second optional parameter is left or right, which puts Item in a specific hand, if applicable; if this parameter is used, then 0 or 1 must precede it (usually 0).
It only works on baseIDs. Consequently, it will equip an item of that type already in inventory, or a create a new copy of the item if it is not already in inventory. You cannot use it to transfer a specific item from your inventory (or the ground, or a container) to an NPC.

The opposite command is unequipitem, and works with the same basic syntax. See also equipspell and equipshout.

equipspell <Spell ID> <Casting Sources>

Equipping the given spell on a particular casting source.

<Casting Sources> could be:

left: The caster's left hand.
right: The caster's right hand.
voice: Used for Shouts.
instant: Used for Potions and Powers.

Example:

player.equipspell 12fcd left will equip Flames to player's left hand.
player.equipspell 12fd2 right will equip Heal Other to player's right hand.

Users have reported being able to do things like force a lesser power that is normally triggered with the Shout key to be equipped as a left-hand spell, and other things not normally possible; such antics may produce unexpected or undesirable results, so save first before experimenting.

It seems impossible to equip actual shouts with this command to player (use equipshout instead).

equipshout <Shout ID>

Equipping the given shout.

Example:

player.equipshout 44250 will let the player equips Dragonrend.
player.equipshout 13e07 will let the player equips Unrelenting Force.

forceAV <attribute> <nn>

Force to modify the value of attribute

ForceAV modifies the attribute value by registering a permanent modifier (positive or negative) of the amount required to force the attribute to the stated value. Displayed player attributes modified in this way will be highlighted (default is green text) to indicate a modifier ('buff' or 'debuff') is being applied.
Also see modAV and setAV

The full list of attributes is provided at Actor Value Indices

getAV <attribute> Get value of attribute This will return the value of the specified attribute (a.k.a. actor value) for the specified target. You can select a target with the mouse, or enter the refID of the target followed by a period before the command. For example, player.getav heavyarmor will return the player's Heavy Armor skill value. For a list of all of the actor values that can be used, see Actor Value Indices.

getAVinfo <attribute> Get value information of attribute This will print a short list of information about the given attribute (a.k.a. actor value) of the specified target. You can select a target with the mouse, or enter the refID of the target followed by a period before the command. For example, player.getavinfo lightarmor will return information about the player's Light Armor skill, such as the base value (what it was just after character creation), any current temporary or permanent modifiers, etc. For a list of all of the actor values that can be used, see Actor Value Indices.

getlevel <target> Get level of target Gets the level of the targeted character or creature.

GetLocationCleared <locationID> Check an area's clear code. 0 = not cleared, 1 = cleared. You must use the location id, not the name; for example, GetLocationCleared 00018EE2 will check Swindler's Den.
Also see SetLocationCleared.

getrelationshiprank <target> Get the relationship rank of two actors. Should range from -4 to 4. See setrelationshiprank.

getstage <quest ID> Show the current active quest stage. Shows the current stage that the quest is at based on the game's internal stage numbering.

hasperk <perk ID>

Check if the selected actor has a perk with the selected ID

For perk ID codes, see the page for the perk's corresponding skill, indexed at Skills. To find the perk ID code in-game, try help <perkname> 0.

E.g., hasperk 3af84 would return Perk Rank >> 1 if the selected actor has taken the first level of the Two-handed Skull Crusher perk.

incPCS <skill name> Increase the given skill to the next level. For example, entering incpcs lightarmor will increase the player's light armor skill to the next level. No integer or variable may be used after the command - it can only be used to increase a skill one level at a time. Using this command will lead to a normal increase in the player's level with attribute selection and a perk point, unlike the advlevel command.
As an alternative to incPCS, see the advskill command. By comparison, advskill uses a more complex leveling system but can be used to advance a skill by any number of levels at once.

kill <Actor ID (optional)>

Kill the selected actor (NOT the optional Actor ID).

Open the console, click on the actor you want to die, type kill and press Enter. Entering an optional Actor ID will treat that actor as the person who killed the target^{[verification needed]}, which can cause other NPCs to attack the actor as they would a murderer. Specifying the Player as the Actor ID will assign blame to the player, counting the kill as a murder if the target was non-hostile and possibly incurring a bounty if other NPCs witness the death.

Some actors (primarily NPCs, not creatures) can be flagged as 'essential' by the game and thus will not die. In this case, the character will instead crouch and stumble around for a while; however, this stumbling can usually be ended early by using the resurrect command on him/her.

lock <level> Lock targeted object (i.e. door, container) with a difficulty of <level>. Values of <level> will display in the tooltip for the locked object as follows: 0 - 25: Apprentice, 26 - 50: Adept, 51 - 75: Expert, 76 - 100: Master, 101+: Requires Key.

MarkForDelete Delete an object. Deletes the targeted object the next time the area (cell) it resides in is reloaded. Useful for removing specific unwanted furniture/decoration from homes. Be careful as there's no way to restore deleted objects. Objects marked for delete will show [D] next to their ref ID if you re-target (re-click) them. Can be used to remove Ash Piles and Ghost Remains, which otherwise never get removed from the world.

modAV <attribute> <nn>

Modify value of attribute by <nn> amount

ModAV modifies the attribute value by registering a permanent modifier (positive or negative) of the value stated. Displayed player attributes modified in this way will be highlighted (default is green text) to indicate a modifier ('buff' or 'debuff') is being applied.
Also see forceAV and setAV

The full list of attributes is provided at Actor Value Indices

moveto <actor ID>

Move a character to specified actor and vice versa.

Example 1 - move Player to an object or NPC: player.moveto 0002BFA2. Using this code will instantly teleport you to Hadvar's position. You must use RefID

Example 2 - move an object or NPC to the Player: type prid 000A2C94, Enter. Then, type moveto player, Enter. Using this code will instantly put Lydia next to you. This code is especially useful for a follower/NPC who's just disappeared after a quest due to a bug in game; e.g. Lydia is disappeared after The Break of Dawn quest. You can also select an object and type moveto player which will move the selected object to your feet and orient it based on the camera's angle.
Also see placeatme

movetoqt <quest ID> Move to quest target Example: movetoqt da01. Using this code will instantly teleport you to the target (i.e., the marker on the map) of the quest. It does not advance the quest in and of itself, but may bring you into a situation which might immediately do so. It takes you to the ultimate current target of the quest in its respective cell - so it doesn't just take you to the next doorway you need to go through. It doesn't skip over to the final stage of the quest, either - you are delivered to the target of the current stage of the quest. Use caution, as you will be placed right on top of or as close to the current marker as possible, which may position you in the middle of a group of enemies, or on top of a trapdoor, etc. See the main index of Quests for the quest ID codes.

openactorcontainer 1 Open a character's inventory. Opens selected NPC's inventory to allow the player to add/remove items as if it were any other container.

paycrimegold (<jail?> <confiscate?> <faction ID>)

Pay the bounty.

Pay the bounty for the faction targeted NPC belongs to (the bounty gold will be removed from your inventory). The <jail?> parameter controls whether you are sent to jail: entering 1 means you will be teleported to the respective faction's jail (the default), entering 0 means you will stay put. The <confiscate?> parameter controls what happens to your stolen items: entering 1 means they are confiscated, entering 0 means you keep them (the default). If you don't specify either parameter, you will be sent to jail but keep your stolen items. The faction ID is only needed if you can't target an NPC. May also help in case guards attack you on sight. Faction ID's are given below:

factionid	faction
00028170	Crime Faction Falkreath
000267E3	Crime Faction Eastmarch (Windhelm)
00029DB0	Crime Faction Haafingar (Solitude)
0002816D	Crime Faction Hjaalmarch (Morthal)
0002816e	Crime Faction The Pale (Dawnstar)
0002816C	Crime Faction The Reach (Markarth)
0002816B	Crime Faction The Rift (Riften)
000267EA	Crime Faction Whiterun
0002816F	Crime Faction Winterhold
xx018279	Crime Faction Raven Rock (Solstheim)

placeatme <actor/object ID> Spawn specified actor or object at current position. Example: player.placeatme 000fea9b. Using this code will instantly summon an instance of an object or NPC at your position. The above example summons a dragon. Not recommended for named NPCs. This code uses the Object (base) ID and not specific reference ID as it is creating a new instance of that object/actor in the world; using it with named NPCs can result in duplicates unless the original was somehow removed.
Also see moveto which can summon named NPCs by refID using the following commands: prid RefID & moveto player

playidle <idle ID> Play an animation (idle) on the specified actor. Example: playidle IdleOffsetArmsCrossedStart. See the list of idles.

pushactoraway <actor ID> <number> Push an actor away in a random direction. Example: pushactoraway 14 1337. Will push or launch your character in a random direction. If you enter negative amount, example: pushactoraway 0001A6B8 -200, will pull the selected actor to your character position.

recycleactor <destination reference (optional)>

Revive/Reset targeted NPC or object.

Can be used to reset an NPCs reference/revive dead NPCs. If you've already looted a corpse, they may come back headless (especially Nords). Their inventory isn't reset, except for their weapon. Enemies will prioritize other NPCs of opposing factions (like Stormcloak vs Imperial), and ignore the player until the opposing NPCs are dead. The optional Destination Reference is untested, probably refers to coordinates or a cell id.

When used on containers, it acts like resetinventory.
When used on objects, it will reset them to their original positions and states. It can be convenient if you mess something up and want to restore the order.
When used on the player, their inventory is not replaced, but the following items are added:

Equipment
Full set of Iron Armor, including shield
Iron Dagger
Iron Sword
Iron War Axe
23 Iron Arrows
Long Bow
Potion of Light Feet
5 Potions of Minor Healing
5 Potions of Minor Magicka
5 Potions of Minor Stamina
2 Potions of Resist Fire
Potion of the Warrior
The Book of the Dragonborn
10 Lockpicks
2 Torches

removeallitems <actor or container ID> Remove all items from a character's inventory. E.g., player.removeallitems will remove all items from your character's inventory or 'removeallitems <click on character> for remove all items of particular character. Optionally, after the command, enter the reference ID of an actor or container to transfer all the items in question into the referred actor/container.
Also see duplicateallitems

removeitem <item ID> <count> Remove the specified amount of an item from a character's inventory. E.g., player.removeitem 000669A5 5 will remove five leeks from your player's inventory. Changes to an NPC's inventory will usually appear immediately if you're pickpocketing them when you open the console.

removeperk <perk ID>

Remove the specified perk from a character's skills.

For perk ID codes, see the page for the perk's corresponding skill, indexed at Skills.

Important note: To remove perks from an established tree, you will need to backtrack through the entire tree. Meaning, start from the top and work your way down. In perks with ranks, you will need to remove rank 5/5, then 4/5, etc. Also, using removeperk will only remove the perk. It will not refund the perk points.

E.g., player.removeperk 000babe8 will remove Barbarian rank 1/5.

removespell <spell ID>

Removes a specific spell from a character's spell book. Also works with powers, abilities, blessings, and diseases, but not shouts

For a spell's ID code, see the page for its corresponding magic school, indexed at Spells. For other applicable IDs, see: Powers and Abilities, Blessings, or Diseases.

E.g., player.removespell 00092c48 will remove the 'Beast Form' power from the player's spell book.

resetAI Reset an NPC's AI. Can be used to calm down a non-enemy NPC if you attack them. In battle, the enemy is forced to sheath their weapon, then pull it out again and reacquire their target.

resethealth Restore a character to full health. Example: player.resethealth Restores your health to 100%

resetinventory Reset a container or a character's inventory. Resets a character's inventory to its default. Example: If you use removeallitems on an NPC and enter resetinventory everything will respawn and re-equip to its defaults. Can be used to pickpocket the same item multiple times. Works on dead NPCs and containers/chests, so you can loot the same corpse/container multiple times. Containers are slightly randomized, so items may vary depending on the containers loot settings.

RestoreActorValue <attribute> <nn>

Restore the value of attribute by <nn> amount

Restores a damaged skill or attribute up to its normal value. Example: lose 50 health and enter player.restoreactorvalue health 100 and you recover 50 health since it can't restore more than its normal value. Doesn't fix attributes/skills damaged by modAV or forceAV or setAV
Also see DamageActorValue

The full list of attributes is provided at Actor Value Indices

resurrect <1> Resurrect target actor Unless you use this command the instant the NPC is killed, the game will still register the target as 'Dead' and they will subsequently not be mentioned in dialogue and sometimes specifically referred to as 'Dead' during a quest. Adding a tag of '1' at the end (i.e., resurrect 1) will make the target get up instead of vanishing and reappearing, thus allowing them to keep their equipment. ^{[verification needed — see talk page]} If an NPC's corpse has vanished already, you will also need to enable the NPC. Using this on the player character will not dismiss the 'Load last save?' screen, and the camera will behave as if you were still lying dead on the ground. However, if you use the resurrect command before the loading message appears, the player will revive, but the camera will be centered on the feet rather than the head. Note that accidentally using this command on yourself while you're still alive can also have unexpected consequences, among them losing the ability to dual-cast spells (which will be fixed on reload), and losing any blessing effects (but not the blessing itself - which can be complicated in the case of Standing Stones. The game will not let you restore that Standing Stone power unless you first visit another Standing Stone and come back.) NPCs who are dead at the beginning of the game (such as Mage) cannot be resurrected via this command.
Also see kill.

say <dialog topic ID>

Makes the targeted actor say a specific dialog topic.

Useful for forcing bugged NPCs to say a specific dialog topic if entering the dialog window is impossible for some reason. Any scripts for the dialog topic will also run as if the actor had said it normally. May have unintended effects if the dialog topic is invalid for that particular NPC.

E.g., say DA04SeptimusBringBloodBranchTopic

setactoralpha <0–100> Change the selected actor's alpha/opacity. Useful for repairing unwanted graphic glitches after adding and removing certain permanent spell effects. E.g., player.setactoralpha 100 will reset unwanted invisibility effects and make your character visible again.

setAV <attribute> <nn>

Set value of attribute

SetAV sets the level value of the attribute to the stated value. Example: You can player.setav block 100 to set your Block to 100 and take advantage of having a high level Block without receiving any levels (and therefore any perks). The same works for dropping the skill level. You can also do it for Health, Stamina, or Magicka etc. And you can target it for an NPC by using prid <RefID> of an NPC first; then just type setav health 500 to give the specified NPC 500 Health.
Also see forceAV and modAV

The full list of attributes is provided at Actor Value Indices

setessential <base ID> <0 or 1>

Set a character as mortal (0) or immortal (1).

This command can be used to make any NPC unkillable. When a character set as essential takes nearly fatal damage, they collapse onto their hands and knees (Also known as Bleedout) and stumble around for a period of time, instead of dying.
Note that the base ID and not the ref ID must be used. The ref ID is what appears when clicking on an object with the console open. To find an NPC's base ID, however, you can either a) browse to their respective page (see: People and/or NPCs) or b) use the help function in-game to search for them by name, recording whatever value matches their name under the 'NPC_' category of result. Once you have the base ID, enter the command using either 1 to set him/her immortal or 0 to set him/her mortal. For example, setessential a2c8e 1 would set Lydia as immortal.

Be careful when making an Essential NPC mortal, if they die you will likely be unable to access the associated quest or story. However, a simple save reload will fix if you haven't save over all the files where the character is still alive(and either non-essential or essential)
Related functions: To check whether an NPC is essential to begin with, select him/her in the console (so that the ref ID appears), and enter IsEssential - if the console returns '1.00', the NPC is essential.
It is also possible to set the player them self as essential with the base ID of 00000007, However upon entering the 'bleedout' stage, the player will sometimes not get back up (usually upon the first time in a new area or after having recently set yourself as essential), however, simply entering your inventory and drinking a health potion will fix this immediately (any health potion used during bleedout will return you to full health). Usually, your character will drop down to their hands and knees, and then immediately get back up with full health.

setghost <0 or 1>

Set ghost mode for the targeted NPC.

Makes the NPC immune to all combat mechanics such as melee attacks, spells, AOE, and shouts while active. The player can still collide with the NPC by running into them.

For example: Serana is in ghost mode to hide her from all attacks until she becomes active in the Dawnguard questline.

setgs <setting> <value> Set game setting. Doesn't seem to be preserved in saves; must be reset each time the game loads. Example: setgs fJumpHeightMin <height> sets the jump height for the player.

setlevel <multiplier> <modifier> <min> <max>

Set NPC level

Just like other target commands, type prid <RefID> of an actor/NPC first. If you prefer to click on the NPC while in the command console, make sure the ID you see is of the targeted NPC and not an object.

If you input setlevel 1000 0 1 100 that NPC will be equal level you are and will level with you up to level 100 and will start at level 1 if you're level 1.

Macro scheduler 14 crack. If you like Macro Scheduler enough to go searching for a crack for it then why not just buy it. It's a lot less hassle and you won't risk infecting your computer with. Jan 27, 2018 - Mar 12, 2013 Hacking-01 - Macro Scheduler Lucas Moyano. Unsubscribe from Lucas Moyano? Cancel Unsubscribe. Subscribe Subscribed. Feb 28, 2018 - Downlaod at:.www.safeandfreefiles./macro-scheduler-automation-tool-14-0-full-download-with-crack/ Tags- Free Download Macro.

Variable	Description
<multiplier>	Determines the base level in terms of the player's current level. Specified in tenths of a percent (i.e. 1000 means 100%, 500 means 50%).
<modifier>	This number is added to the base level determined by <multiplier>. Can be negative or zero.
<min>	The minimum level of the NPC (must be at least 1).
<max>	The maximum level of the NPC (at most 100, unless you have patch v1.9 patch or use the level uncapper mod).

SetLocationCleared <locationID> 1 Set whether an area has been cleared. You must use the location id; if you wish to clear Swindler's Den, for example, use 00018EE2, not the name. Also see GetLocationCleared.

setnpcweight <0–100>
(snpcw) Set the weight of the selected NPC and updates the model to reflect the new weight. Despite its name, this also works on the player's model. e.g. player.setnpcweight 0 changes the player's appearance to be as if the 'Weight' slider were all the way left. 100 would be all the way to the right. Saving and re-loading a game after it's been used on an NPC may result in neck seams, as NPC head meshes are pre-modeled and not procedurally generated to the new weight value.

setownership <ID> Sets ownership of the targeted item. You can set the owner of the targeted item with a faction ID or a character's base ID. If you don't add the parameter, the default owner would be yourself. This can be used to remove the 'stolen' tag from any items. Simply drop the item on the ground, open the console, click on the item, and enter the command. It can be difficult to select certain items. Can also be used to remove the 'owned' attribute of beds and gain the ownership of a stolen horse.

setrace <race>

Change a character's race.

Doing this will allow you to change the race of an actor. If player.setrace is used, you can change your own race without using showracemenu. Upon using this code, the character's hand will be bound like in the beginning of the game, but this can be undone by drawing a weapon. This will not mess up attributes/skills. Creatures are available as races as well (e.g., player.setrace dragonrace), but most creatures will have a buggy camera position in third person. You can get most race codes with the help race 0 command. Use PageUp and PageDown to scroll to the races at the top of the list. Unlike most other commands, the race needs to be specified in plain text and not the race's BaseID (i.e. player.setrace nordrace). See setplayerrace for additional details.

Playable Races
Normal	Vampire
ArgonianRace	ArgonianRaceVampire
BretonRace	BretonRaceVampire
DarkElfRace	DarkElfRaceVampire
HighElfRace	HighElfRaceVampire
ImperialRace	ImperialRaceVampire
KhajiitRace	KhajiitRaceVampire
NordRace	NordRaceVampire
OrcRace	OrcRaceVampire
RedguardRace	RedguardRaceVampire
WoodElfRace	WoodElfRaceVampire

setrelationshiprank <target> <#> Change the relationship between two actors 0=acquaintance, 1=friend, 2=confidant, 3=ally, 4=lover, -1=rival, -2=foe, -3=enemy, -4=archnemesis. (All other values are unassigned ranks and will default to 'acquaintance'.)

setscale <#> Scale size of target. Scales the size of a chosen target. Starting from small 0.1, normal 1, and 10 at max size. Acceptable targets can be any NPCs or objects in the world. You cannot change the size of items.

setstage <quest ID> <stage #> Set the current stage of the given quest. Example: setstage ms01 100. The setstage command is useful for advancing broken quests, finishing quests instantly, or for skipping ahead to a certain point in a quest. You can find the quest's ID code, as well as the various stages of the quests and their corresponding stage numbers, on the respective quest page. To start, see the main index of Quests.

setunconscious <integer> A value of 1 will be unconscious Example: setunconscious 1 makes an NPC or the player stand in place as if it's in a trance or their AI is disabled. You can do whatever you want to them and they won't react. They remain that way until you use setunconscious 0. They will act like nothing happened, so if you steal from them and wake them back up it will be as if they didn't see anything. They can also wake up if you get their health to a critical level, and will either fight back or run away. The effect is equivalent to the player using wait and coming out of it early due to an attack.

inv/showinventory Display the base IDs of every item in a character's inventory. These IDs can be used in the console to modify a character's or the player's inventory. E.g., with five Leeks in a person's inventory, player.showinventory will display '5 - Leek (000669A5)', and you can use player.additem 000669A5 5 to obtain five more leeks.

shp <parameter #1-parameter #9> Set HDR parameters The 9 HDR parameters are in floating point. Each one affects something different. The effects stay until you load a save or switch areas. Example: shp 1.00 0 0.50 0.01 9.00 .1 .99 100 1.0000

sifh <#> Set whether an actor should ignore friendly hits. E.g., sifh 1 will make the selected actor ignore friendly hits.

sqs <quest ID> Display stages of a quest Lists all stages of that quest and shows if a stage is achieved.

str <0–1.000000> Set the refraction value of the selected target. E.g., str 1.000000 will set refraction to its maximum value, str 0.000001 will make the target completely invisible, str 0.000000 turns off refraction reverting the target to its normal appearance. str 0.000000 will completely mess up a character's eyes and eyelashes. Can be used on any targetable object from NPC/player to pieces of the architecture.

teachword <word> Teach a dragon shout. Teaches a specific dragon shout by code. Each level of a word has a specific code. Use the help command to find the shout's code, or see Dragon Shouts.

unequipitem <Item baseID> Unequip item from selected NPC With the selected NPC you can use unequipitem<ItemID> to get them to unequip an item but leave it in their inventory. The opposite command is equipitem, and works with the same basic syntax. No error results from unequipping an item the NPC doesn't have. The player-character equivalent command is player.unequipitem.

unlock Unlock the targeted object. Unlocks the targeted door, container, etc., including 'Requires Key'-level locked objects.

unlockword <word> Unlock a dragon shout. Unlocks a specific dragon shout by code. Each level of a word has a specific code. Use the help command to find the shout's code, or see Dragon Shouts.

Untargeted Commands[edit]

These commands do not require a target reference.

bat Execute a batch file Executes a .txt file with console commands in it, handy for certain otherwise tedious actions.

caqs Complete all quest stages Finishes every quest in the game, not just the ones you've started, essentially completing the game. Not recommended for general use. May crash your game. Note: This will unlock several quest related Steam achievements if they have not been unlocked yet. See also: saq

coc

Transport to <cellname>

Transports to the center of a named cell (coc is short for CenterOnCell.); i.e., if you want to go to Riverwood write coc Riverwood in the console. You can get most location codes with the help location 0 command. I.e. help breezehome 0 will tell you that the correct code is WhiterunBreezehome or that Sovngarde can be reached with Sovngarde01.

coc qasmoke will transport to the Skyrim testing hall (for QA testing; inaccessible otherwise.) Note: The enchanted armor and weapons cabinets contain huge piles of items which can take some time to load; the game may appear to freeze for a while if you open one.

cow

Transports to cell <cell x, cell y> in <worldspace>

Transports to the center of cell [cell x, cell y] in world space. (cow is short for CenterOnWorld.) The outdoor worldspace of Skyrim is Tamriel so to transport to the center of cell 5,7 in Tamriel you would put cow tamriel 5,7 in the console.

These points will put you at the stables or right in front of each city but not inside.

City gate cells
City	Cell
Whiterun	4	-4
Dawnstar	8	25
Solitude	-15	25
Markarth	-42	0
Morthal	-10	15
Falkreath	-7	-21
Winterhold	27	24
Windhelm	33	7
Riften	42	-23
High Hrothgar	10	-10

csb Clear screen blood Removes all blood from the screen. Useful when taking screenshots.

EnablePlayerControls <Movement> <Fighting> <POV> <Looking> <Sneaking> <Menu> <Activate> <Journal Tabs> <POV Type> Re-enables player controls Removes restrictions on player's control. Unlike the script command, this does not appear to allow controls to be disabled. Note: If used in carriage at the game start, unexpected bugs may occur or the game may crash.

fov Set fov <angle> Will change the Field of View to <angle>. Default is about 65 and using the command with no value will set the fov to 75. This change will reset if the game is restarted or if settings are changed by the Launcher. Values between 80 and 107 may be most suitable for wide screen PC users. 180 is the maximum, values higher will be accepted, but will still have the effects of 180.

Force Weather

Changes the current weather to the specified value (Note: Using this command will not permanently change the weather). It is only temporary, and will reset after some moving around. Typing ,1 after the formid without spaces will prolong the weather of your choice (for example, fw 10e1ec,1). Valid formids are:

Weather formids

formid	edid
0010FEF8	SovngardeDark
0010FE7E	RiftenOvercastFog
0010E3D4	EditorCloudPreview
0010E1F2	SkyrimClear_A
0010E1F1	SkyrimCloudy_A
0010E1F0	SkyrimClearSN_A
0010E1EF	SkyrimCloudySN_A
0010E1EE	SkyrimClearTU_A
0010E1ED	SkyrimCloudyTU_A
0010E1EC	SkyrimClearFF_A
0010E1EB	SkyrimCloudyFF_A
0010E1EA	SkyrimClearRE_A
0010E1E9	SkyrimCloudyRE_A
0010E1E8	SkyrimClearCO_A
0010E1E7	SkyrimCloudyCO_A
0010E1E6	SkyrimClearMA_A
0010E1E5	SkyrimCloudyMA_A
0010E1E4	SkyrimClearVT_A
0010E1E3	SkyrimCloudyVT_A
0010DA13	FXWthrInvertWindowsWinterhold
0010D9EC	SovngardeClear
0010C32F	FXSkyrimStormBlowingGrass
0010A7A8	SkyrimCloudyVT
0010A7A7	SkyrimFogVT
0010A7A6	SkyrimOvercastRainVT
0010A7A5	SkyrimClearVT
0010A245	SkyrimCloudySN
0010A244	SkyrimClearSN

formid	edid
0010A243	SkyrimCloudyTU
0010A242	SkyrimOvercastRainTU
0010A241	SkyrimStormRainTU
0010A240	SkyrimClearTU
0010A23F	SkyrimCloudyFF
0010A23E	SkyrimFogFF
0010A23D	SkyrimOvercastRainFF
0010A23C	SkyrimStormRainFF
0010A23B	SkyrimClearFF
0010A23A	SkyrimCloudyRE
0010A239	SkyrimFogRE
0010A238	SkyrimOvercastRainRE
0010A237	SkyrimClearRE
0010A236	SkyrimCloudyCO
0010A235	SkyrimFogCO
0010A234	SkyrimClearCO
0010A233	SkyrimCloudyMA
0010A232	SkyrimFogMA
0010A231	SkyrimOvercastRainMA
0010A230	SkyrimClearMA
00106635	KarthspireRedoubtFog
00105F40	SkyrimDA02Weather
00105945	SolitudeBluePalaceFog
00105944	SolitudeBluePalaceFogNMARE
00105943	SolitudeBluePalaceFogFEAR
00105942	SolitudeBluePalaceFogARENA
00105941	BloatedMansGrottoFog
00104AB4	SkuldafnCloudy

formid	edid
0010199F	SkyrimMQ206weather
00101910	FXWthrInvertLightMarkarth
000ECC96	FXWthrInvertWindowsWindhelm2
000D9329	HelgenAttackWeather
0005ED7A	FXWthrInvertLightsSolitude
0008282A	FXWthrInvertLightsWhiterun
0008277A	FXWthrInvertWindowsWhiterun
000D4886	FXMagicStormRain
000D299E	SkyrimOvercastWar
000C8221	SkyrimStormSnow
000C8220	SkyrimStormRain
000C821F	SkyrimOvercastRain
000C821E	SkyrimFog
00075491	FXWthrSunlightWhite
0007548F	FXWthrSunlight
00048C14	BlackreachWeather
000AEE84	FXWthrInvertWindowsWindhelm
000A6858	WorldMapWeather
000923FD	SovngardeFog
000777CF	FXWthrInvertDayNighWarm
00075DE5	FXWthrCaveBluePaleLight
0006ED5B	FXWthrCaveBlueSkylight
0006ED5A	FXWthrInvertDayNight
0004D7FB	SkyrimOvercastSnow
0002E7AB	TESTCloudyRain
00012F89	SkyrimCloudy
0000081A	SkyrimClear
0000015E	DefaultWeather

GetGlobalValue <Variable> Returns the value of a single global game setting. Example:GetGlobalValue DragonsReturned would tell you whether or not random dragon attacks will take place. See ShowGlobalVars.

GetInCellParam <Cell ID> <Object ID> Checks if an object is in a specified cell. Example:GetInCellParam 5de24 14 would tell you whether or not the player is in helgen keep. getincell >> 0.00= not present, 1.00=present. Can be used to confirm if your character or an NPC is in a particular cell.

GetPCMiscStat <Stat> Returns the value of the (typically meaningless) stats shown in the ESC menu. Shorthand is GetPCMS. Example: GetPCMS 'barters' would tell you how many times you've gone shopping or GetPCMS 'days as a werewolf' will tell you how many days you have been a werewolf. The quotation marks are required in the command to properly identify multiword stat IDs.

help

Returns the IDs of all items, spells, game settings, etc. which have the entered text in their name.

This is a useful command to find the item ID of an object, which can then be used with other console commands.

E.g., help 'Daedric' will list all items, etc. which have 'Daedric' in their name. There is no need to put a '0' for the help command. Quotation marks are required for queries of more than one word (e.g., help 'ancient nord' Use page up and page down to scroll through the results.).

killallactors Kill all actors. Kills all loaded (in currently rendered cells) non-essential actors (NPCs and creatures) immediately. Essential actors will be knocked down. The code killall can be used for identical effect.

load

Loads <name> gamesave.

Loads the corresponding save. E.g.: load autosave1 will load last autosave. If the name contains spaces, it must be enclosed in double-quotes, E.g.: load 'My Skyrim Save'

Useful when stuck, or if showracemenu is opened. See also: save

ModPCMiscStat <Stat> <nn> Adjusts the value of the (typically meaningless) stats shown in the ESC menu by <nn> amount. Shorthand is ModPCMS. Modifies the Player Character Miscellaneous Statistic value by registering a permanent modifier (positive or negative) of the value stated. Example: ModPCMS 'days as a werewolf' -100 will modify how many days you have been a werewolf by a negative 100. The quotation marks are required in the command to properly identify multiword stat IDs.

pcb Purge cell buffer This will free up used memory, often times increasing fps after any given amount of time in game. Best used while in interior cells. However, since it purges cached cells, any cells you visited in the recent past will have to be reloaded completely when reentered.

playercreatepotion <MGEF ID#1> <MGEF ID#2 (optional)> <MGEF ID#3 (optional)>

Creates a potion with up to 3 effects.

Example: playercreatepotion 6b10C gives you a potion of improved nighteye for X seconds. Alchemy Skill determines effect magnitude(based on alchemy skill 1=1%/1Pt,) and duration(duration = Alchemy Skill +1 Sec). Some MGEF effects don't work with potions.

damageactorvalue and modAV will affect the magnitude of alchemy effects without messing with your level/skill progress.

playerenchantobject <object ID> <MGEF ID> <MGEF ID (optional)>

Spawns an object with specified enchantments

Example: playerenchantobject 136D5 109637 109637 would give you imperial armor with two magic resist enchantments.

The Magnitude used for any magic effect is set to your enchanting skill, so 85 enchanting skill = 85% magnitude,85 damage/+85 health/magicka/stamina, 85+1 sec duration(weapons only).

Any effect with an MGEF ID can be added, including special effects normally restricted to NPCs and some perk effects. Perk MGEFs don't show up on equipment or passive effects, but still work. They also use enchanting skill instead of the perks usual value, and stack with the real perk.

Weapons made through the console will always have about 11.5 charges(regardless of enchanting level), and can be recharged. Some effects don't require charges unless grouped with an effect that does require charges. When used on weapons some MGEF are toggled on hit(first hit= on,second hit= off), like improved nighteye.

Enchanted weapons/equipment created with this command cannot be disenchanted, the game will tell you that you already have the effect.

damageactorvalue and modAV will affect the magnitude of enchantments without messing with your level/skill progress.

prid <RefID> Pick reference by ID Select an existing copy of an object/creature/NPC using its reference FormID (the one associated with that particular placed object). All subsequent targeted commands will use this object as the target. This is the same as clicking on the object in the console, but can be used even if the object is invisible or in a different area. Shorthand for PickReferenceID

qqq Fast quit. Quits Skyrim to desktop immediately without further prompting. This sometimes results in crashing or mouse click problems. Mouse problems can be resolved by re-opening and closing Skyrim.

resetinterior <cellID> Reset an entire cell. This command will reset an entire dungeon or location to default, including monsters, traps, chests and loot. E.g., ResetInterior Stillborncave01 or ResetInterior 00015206 would reset the dungeon Stillborn Cave to default; all monsters, traps, and loot would be respawned. If you reset a cell you have just been to, you'll need to use pcb command (purge cell buffer) as well, or the game will reload the buffered version of the cell, with all the modifications you've made to it. Both editorID and formID are acceptable in this command. Using this command in player homes appears to reset the furnishings without clearing the contents of initially empty containers, however, all weapon racks and cases will be empty and mannequins will need to have their inventories removed and replaced. (viz., the bedroom chest)^{[verification needed]}

refini Refreshes all settings. This command loads and re-applies all settings from Skyrim.ini and any .ini with filenames matching currently loaded .esp files.

resetquest <questID> Reset a quest. This command will reset a quest. This command will set all stages of the quest to 0.

saq Start all quests Begins every quest in the game and adds them all to your journal. Not recommended for non-experimental use due to the large number of quests. May crash your game. Note: This will unlock several quest related Steam achievements if they have not been unlocked yet. See also: caqs

save

Write <name> gamesave.

Save game to a named save <name>. If the name contains spaces, it must be enclosed in double-quotes, i.e. save 'My Skyrim Save' Note that this will overwrite an existing save of <name> without prompting.

Appending the parameter '1' will create a file <name>.ess.txt and open a texteditor upon it. This textfile contains a lot of dumped data and takes a while to write out (15 minutes observed) - the console and game is unresponsive during that. See also: load

saveini Save settings to file. This command saves all current settings to an ini file in the Data folder. The file will be named after the last loaded plugin, and will thereafter only automatically load if that plugin is included in the load order.

set to Sets a global variable Sets the value for a global variable. See ShowGlobalVars.

setplayerrace

Set player race.

Doing this will allow you to change your race without using showracemenu. If ID is not provided race menu will appear.

You can get most race codes with the help race 0 command. Use PageUp and PageDown to scroll to the races at the top of the list. Unlike most other commands, the race needs to be specified in plain text and not the race's BaseID (i.e. setplayerrace nordrace). Creatures are available as race as well, but most creatures will have a buggy camera position in 3rd person. SetRace racename can also be used. Upon using this code, the character's hand will be bound like in the beginning of the game, but this can be undone by drawing a weapon. Will mess up attributes/skills.

set playeranimalcount to <qty>

sets number of animal followers

used to remove a lost pet from your party set playeranimalcount to 0

Note: doesn't remove any actual follower, just reset the count to the selected number (1 or 0). If used with an animal follower next to you that isn't lost, you can recruit another one.

set playerfollowercount to <qty>

sets number of followers

used to remove a lost follower from your party set playerfollowercount to 0

Note: doesn't remove any actual follower, just reset the count to the selected number (1 or 0).

set timescale to <qty>

sets the speed of how fast time advances in-game

Default value is 20. Setting the value to 1 will make time advance at the same rate as the real world. Values down to 0 are possible, where less than 1 represents game time at a fraction of real time and 0 freezing the time of day completely.

Note: NPCs are unable to cross cell boundaries when timescale is less than 1. Fast traveling while timescale = 0 may also prevent your game from loading properly.

setpqv <quest form ID> <quest variable ID> <desired variable>

Sets a quest variable

Sets the quest variable to something else, typically either true/false or a number. Use the sqv command to check all the current quest variables for a quest.

E.G. setpqv DLC1NPCMentalModel LockedIn_var False

SexChange Switches the player or an NPC's gender Switches the player's gender; does not require a value. Can be used on an NPC if you target them. A fun thing to note is that this code does not change the face and voice of a character. Can be used on mannequins to show female outfits. It is possible to use this command to fix the lingering sound effect bug that some characters seem to suffer, just remember to use the command twice to return to your original gender.

SGTM Changes the Gametime Multiplier to a specified value for slow motion, and fast forward type effects Allows you to control the gamespeed, making it easier to capture screenshots of action on slower speeds. Causes issues above 2.0 and below 0.10, except when 0. This is different from timescale as timescale does not affect combat and movement and dialog where this setting does. Example: sgtm 2 will make the game run in fastforward. Note: This setting is automatically reset back to 1 (default) when killmoves are executed.

ShowGlobalVars Shows all current game variables This will list all current game variables, which can then be changed with the set command. You can scroll through the list with the PgUp and PgDown keys.

ShowMessage Shows a message E.g., ShowMessage 000A81FF will display the 'Playtesting Temporary Message'.

showracemenu Opens the character creation menu. Note: Using this command to alter one's race will reset skills and health/magicka/stamina to default levels. This command can be safely used to alter a character's appearance without causing any unwanted side-effects as long as race is not changed. However, it should be noted that upon completing your changes and choosing a name for your character, all temporary active effects (such as Gift of Charity or shrine blessings) will be removed. Racial resistances will no longer be listed in Active Effects until the game is loaded from the main menu, at which time racial resistances will be automatically reapplied. Permanent active effects such as those from guardian stones or perks will not be lost. Active effects granted from enchanted items will not be listed until the items are re-equipped.

showracemenu <race> Changes the player's race. Example: showracemenu bretonrace will make your character into a Breton. This variation of showracemenu doesn't actually show the race menu, but instead works like setplayerrace <race>. Skills bonuses/powers change to reflect new race, but it messes up skills/attributes like showracemenu past lv1. Setting race to 'nordrace' from any other race seems to result in a no head glitch unless used from the chargen menu.

spf <file name> Save PC Face Saves the player face i.e. slider settings in showracemenu into a text file in Skyrim folder, which can be later imported into Creation Kit. Do not use any file extension, .npc will be added automatically.

sqo Itemizes quest objectives and their states Shows a human friendly list of active and completed quest objectives for currently active quests

sqt List quest ids and targets List all active quest IDs and their targets. Useful for finding the 'questID' parameter for targeted quest commands such as movetoqt <QuestID>

stp <unknown1> <unknown2> <unknown3> <chroma> Set tint parameters The chroma value ranges from 0 to 1 and is inverted, so stp 1 1 1 1 produces a black & white image, while stp 1 1 1 0 disables tint filtering altogether.

All Known Commands[edit]

Using Batch Files with the `bat` Command[edit]

Skyrim provides a simple batch file mechanism so you can customize your game play quickly and without repeatedly typing console commands.

Example: bat mybatchfile; runs all of the console commands in the file Skyrimmybatchfile or SkyrimDatamybatchfile.txt. Notice that the file you put in Skyrim directory mustn't have an extension, while the one in SkyrimData needs a .TXT extension. The second option is preferable - first because you don't need to change file extension and second because it keeps the root directory clean. Also a file that goes to Data folder can be shipped along with mod and placed by all Mod Managers.

To use the feature you:

Create a text file that contains a list of console commands (one per line).
Place the file in your Skyrim installation directory or in SkyrimData.
Start the game.
Bring up the console.
Type bat followed by the name of your batch file, for example bat mybatchfile.

Skyrim batch files are lists of console commands that are run one after the other. They have no loops, tests, or other logic and execution doesn't stop if there's a problem with one of the commands. You can create any number of batch files, each with its own purpose.

Guidelines for Using Commands in Batch Files[edit]

Most Skyrim console commands can be run from a batch file. For example:

Skyrim Console Command Remove Spell Effect

Toggle commands work in batch files. These include showing and hiding NPC conversation subtitles (ShowSubtitle), turning on and off grass display (TG), enabling and disabling god mode (TGM), and so forth.

Targeted commands with an explicit reference work fine. For example, you can use Player.Additem f 1000 in a batch file to add 1000 gold to your inventory. If you want to give Lydia 1000 gold, use A2C94.Additem F 1000 (A2C94 being the Reference ID of Lydia).

PRID (Pick by Reference ID) selects an item, NPC, etc. Using PRID to select an NPC before performing additional commands that you want to apply to that NPC works fine, for example prid a2c94 then setclass 13176 will cause Lydia to level up correctly.

Miscellaneous commands such as FOV or FW can also be run from batch files.

The COC command cannot be run from within a batch file (the game will crash to desktop). ^{[verification needed — see talk page]}

Example for using a Batch File to create an alternative start[edit]

With the above method you can actually create an alternative start to the game. In addition to a batch file, you also need to edit the Skyrim.ini file, which can be found in your C:UsersYOUR_USER_NAMEDocumentsMy GamesSkyrim folder.

Open your Skyrim.ini file and add the line SStartingCell=WhiteRiverWatch01 under the [General] tab.
Adding this line causes Skyrim to bypass the Continue - New - Load - Credits - Quit screen, and starts a new game - without the prisoner video sequence. Once you have created a new character, you will need to remove it again.
Create an empty .txt file in your Skyrim folder (where the TESV.exe is located) and name it bandit (or bandit.txt in the SkyrimData folder).
Paste the code sniplet below the numbered list into the new file.
Start a new game and you will not see the intro, and will begin in the White River Watch cave.
Open the console and type bat bandit.
Create your character.

Code to copy into the bandit[.txt] file:

Using this method, you can visit Helgen before it is destroyed and you can also do the side missions. But without further editing, the Main Quest will not start (see the Quest Stages section of Unbound to find out how to start the main quest anyway).

Retrieved from 'https://en.uesp.net/w/index.php?title=Skyrim:Console&oldid=1968158'

General Information[edit]

Accessing the Console with Non-English Keyboards[edit]

Commands[edit]

Toggle Commands[edit]

Targeted Commands[edit]

Untargeted Commands[edit]

All Known Commands[edit]

Using Batch Files with the bat Command[edit]

Guidelines for Using Commands in Batch Files[edit]

Skyrim Console Command Remove Spell Effect

Example for using a Batch File to create an alternative start[edit]

Using Batch Files with the `bat` Command[edit]